Summary
Release 41.30 exposes vehicles as Scene Graph entities (a component on them casts to fort_vehicle). Attaching other entities to such a vehicle entity is broken in a running session. An entity re-parented under the vehicle entity disappears immediately. An entity attached via entity_origin follows the vehicle but appears to keep its replication/relevancy anchored at a stale position (the world origin or the entity’s pre-attach position): it follows relatively smoothly near that spot, then increasingly stutters and lags behind as the vehicle drives away, and eventually disappears entirely. This makes vehicle-relative entity attachment unusable. Possibly vehicle-entity-specific, possibly a general Scene Graph replication/relevancy issue.
Please select what you are reporting on:
Unreal Editor for Fortnite
What Type of Bug are you experiencing?
Verse
Steps to Reproduce
- In a UEFN island, place a Rocket Racing vehicle spawner.
- Create a Scene Graph entity with a mesh component sized as a drive-through volume on the vehicle’s path (queryable, so overlap events fire).
- Create two more entities, each with a visible cube mesh component.
- Attach the Verse component below to the volume entity and link the two cube entities into its editable fields.
- Build Verse, start a session, and drive the rocket racing car through the volume so both cubes attach.
- Keep driving, moving progressively farther away from the world origin and from where the cube entities were originally placed.
using { /Fortnite.com/Vehicles }
using { /Verse.org/SceneGraph }
using { /Verse.org/Simulation }
using { /Verse.org/SpatialMath }
vz_vehicle_attach_probe_component<public> := class<final_super>(component) {
@editable
OriginCubeEntity<public>: entity
@editable
ReparentCubeEntity<public>: entity
# Scene graph transforms are centimeter-scaled: the origin cube parks
# 6 m ahead of and 1 m above the vehicle origin.
OriginOffset: vector3 = vector3 { Forward := 600.0, Left := 0.0, Up := 100.0 }
# The re-parented cube parks 2 m above the vehicle origin.
ReparentOffset: vector3 = vector3 { Forward := 0.0, Left := 0.0, Up := 200.0 }
OnSimulate<override>()<suspends>: void = {
if (Mesh := Entity.GetComponent[mesh_component]) {
loop {
OverlappingEntity := Mesh.EntityEnteredEvent.Await()
ProbeOverlappingEntity(OverlappingEntity)
}
} else {
Print("Probe host entity has no mesh_component")
}
}
ProbeOverlappingEntity(OverlappingEntity: entity): void = {
if (first (Candidate: OverlappingEntity.GetComponents(), fort_vehicle[Candidate]) { Candidate }) {
Print("Vehicle entity found; attaching both cubes")
AttachOriginCube(OverlappingEntity)
ReparentCube(OverlappingEntity)
}
}
# Attach via the origin system: one transform write clears the local
# transform and applies the offset relative to the new origin.
AttachOriginCube(VehicleEntity: entity): void = {
OriginCubeEntity.SetOrigin(entity_origin { Entity := VehicleEntity })
OriginCubeEntity.SetLocalTransform(transform { Translation := OriginOffset })
}
# Attach via re-parenting under the vehicle entity.
ReparentCube(VehicleEntity: entity): void = {
VehicleEntity.AddEntities(array { ReparentCubeEntity })
ReparentCubeEntity.SetLocalTransform(transform { Translation := ReparentOffset })
}
}
Expected Result
Both cubes follow the vehicle at their fixed offsets everywhere on the island: the re-parented cube as a child entity 2 m above the vehicle, the origin-attached cube 6 m ahead and 1 m up, replicating relative to the vehicle’s live position.
Observed Result
The re-parented cube disappears the moment it is re-parented under the vehicle entity and never renders again, although the vehicle stays alive. The origin-attached cube appears and follows the vehicle, but it follows smoothly only while the vehicle drives near the world origin or near the cube’s position from before the attachment (not yet isolated which of the two is the real anchor); the farther the vehicle gets from there, the more the cube stutters and lags behind, until it disappears entirely, as if its relevancy were evaluated at that stale anchor instead of at the vehicle. See the two attached screenshots: the first (near that boundary) shows the origin-attached cube in front of the car and no re-parented cube above it; the second (farther out) shows no attached entity at all.
Platform(s)
PC (Windows)
Upload an image
Additional Notes
Reproduced in UEFN 5.8.0-55979764 (Fortnite Release 41.30). The cast-based vehicle-entity discovery itself works; only the attachment replication misbehaves. Not yet isolated whether this is specific to the vehicle entity (which lives under the simulation entity’s round-lifetime children rather than the level entity) or a general entity replication/relevancy issue. Internal bug database reference, for matching any follow-up to our records: VT7J0J.