Using same event handler for multiple events. How do I differantiate the event sources?

[Enebz]

I am trying to use several switches in one device. The amount of switches is dynamically set from UEFN.

How can I register all the switches to one specific handler function, and recognize WHICH SWICH got changed?

This code makes the switches use the same handler, but I would not know which switch that got it’s state changed.

settings_playerhealth_device := class(creative_device):

    @editable
    HealthSwitches: []switch_device = array{}

    OnBegin<override>()<suspends>:void=
        for (HealthSwitch : HealthSwitches):
            # Register event handler for each switch
            HealthSwitch.StateChangesEvent.Subscribe(HealthSwitchStateChange)

    HealthSwitchStateChange():void=
        Print("HealthSwitchStateChange for ???")

How can I do this?

[Ep8Script]

settings_playerhealth_device := class(creative_device):

    @editable
    HealthSwitches: []switch_device = array{}

    OnBegin<override>()<suspends>:void=
        for (Index->HealthSwitch : HealthSwitches):
            spawn {AwaitSwitchStateChange(HealthSwitch, Index)}

    AwaitSwitchStateChange(HealthSwitch:switch_device, Index:int)<suspends>:void=
        loop:
            HealthSwitch.StateChangesEvent.Await()
            Print("Health switch at index {Index} changed")

[GraemeBB]

This is an option as well:

Wrapping Subscribe() to pass additional data to listeners | Uefn Code Snippet

[funbbtv]

Thanks and how do you know which player/agent trigger it?

[le-8g7e (Lloyd Evans)]

I was going to suggest modifying the above code slightly to use a value returned from StateChangesEvent.Await() but that seems to return an empty tuple instead of the agent I expected. So to modify it it needs a bit of an awkward workaround but I think something like below would work. This could technically not have exactly the same functionality as StateChangesEvent but might still be what you want.

settings_playerhealth_device := class(creative_device):

    @editable
    HealthSwitches: []switch_device = array{}

    OnBegin<override>()<suspends>:void=
        for (Index->HealthSwitch : HealthSwitches):
            spawn {AwaitSwitchStateChange(HealthSwitch, Index)}

    AwaitSwitchStateChange(HealthSwitch:switch_device, Index:int)<suspends>:void=
        loop:
            InstigatorAgent := race:
                HealthSwitch.TurnedOffEvent.Await()
                HealthSwitch.TurnedOnEvent.Await()

            Print("Health switch at index {Index} changed")

I used the TurnedOffEvent and TurnedOnEvent which do return the instigator.