# Verse - Player Reference Device - Capture Area

**URL:** <https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910>\
**Category:** Verse\
**Tags:** unreal-editor-for-fortnite, fortnite-creative, question, fortnite\
**Created:** [May 16, 2024, 3:00pm UTC](https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910 "2024-05-16T15:00:54Z")\
**Posts on this page:** 4\
**Page:** 1

<div class="post-metadata">

**Author:** ![Frechfratze](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/frechfratze/32/932717_2.png) [@Frechfratze](https://forums.unrealengine.com/u/Frechfratze)\
**Post date:** [May 16, 2024, 3:00pm UTC](https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910/1 "2024-05-16T15:00:54Z")

</div>

Hello everyone,

I’m having an issue with my team registration function. Players can register up to four times and automatically registered twice, despite having clearly defined the logic with if statements. This should be a team registration process where players first go to a capture area in pairs of two to be registered with a player reference. I can’t figure out what I’m doing wrong. Does anyone have any ideas on what could be causing this? Thank you in advance for your help!

```auto
using { /UnrealEngine.com/Temporary/Diagnostics }
using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /Fortnite.com/Playspaces }
using { /Fortnite.com/Characters }

TeamManagement_device := class(creative_device):

    @editable
    var CaptureArea1 : capture_area_device = capture_area_device{}

    @editable
    var CaptureArea2 : capture_area_device = capture_area_device{}

    @editable
    var PlayerReference1 : player_reference_device = player_reference_device{}
     
    @editable
    var PlayerReference2 : player_reference_device = player_reference_device{}

    @editable
    var PlayerReference3 : player_reference_device = player_reference_device{}
     
    @editable
    var PlayerReference4 : player_reference_device = player_reference_device{}

    var Team1Players: int = 0
    var Team2Players: int = 0
    var MaxPlayersPerTeam: int = 2
    

    OnBegin<override>()<suspends>:void=
        CaptureArea1.AgentEntersEvent.Subscribe(Capture1)
        CaptureArea2.AgentEntersEvent.Subscribe(Capture2)

    Capture1(Agent:agent):void=
        Print("CAPTURE 1")
        if (Team1Players < MaxPlayersPerTeam):
            if (Team1Players = 0):
                PlayerReference1.Register(Agent)
                set Team1Players += 1
                Print("Registered in Team 1")
            else if (Team1Players = 1):
                PlayerReference2.Register(Agent)
                set Team1Players += 1
                Print("Registered in Team 1")
        else:
            Print("Team 1 is full")

    Capture2(Agent:agent):void=
        Print("CAPTURE 2")
        if (Team2Players < MaxPlayersPerTeam):
            if (Team2Players = 0):
                PlayerReference3.Register(Agent)
                set Team2Players += 1
                Print("Registered in Team 2")
            else if (Team2Players = 1):
                PlayerReference4.Register(Agent)
                set Team2Players += 1
                Print("Registered in Team 2")
        else:
            Print("Team 2 is full")

```

---

<div class="post-metadata">

**Author:** ![ProtonOne](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@ProtonOne](https://forums.unrealengine.com/u/ProtonOne)\
**Post date:** [May 16, 2024, 5:01pm UTC](https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910/2 "2024-05-16T17:01:28Z")

</div>

You can check if the Agent is already registered by using a function from `player_reference_device` in `Fortnite.digest.verse`:

```auto
# Is true when `Agent` is the player being referenced by the device.
IsReferenced<public>(Agent:agent)<transacts><decides>:void = external {}

```

You need to check all 4 PlayerReference devices, so wrap it in a function with the same signature:

```auto
AgentIsRegistered(Agent:agent)<transacts><decides>:void=

```

(the `<public>` part doesn’t matter, so left it out)

The code in context would look like this:

```auto
    OnBegin<override>()<suspends>:void=
        CaptureArea1.AgentEntersEvent.Subscribe(Capture1)
        CaptureArea2.AgentEntersEvent.Subscribe(Capture2)

    AgentIsRegistered(Agent:agent)<transacts><decides>:void=
        PlayerReference1.IsReferenced[Agent] or 
        PlayerReference2.IsReferenced[Agent] or 
        PlayerReference3.IsReferenced[Agent] or 
        PlayerReference4.IsReferenced[Agent]

    Capture1(Agent:agent):void=
        Print("CAPTURE 1")
        if( AgentIsRegistered[Agent] ):
            Print("Already Registered")
        else if (Team1Players < MaxPlayersPerTeam): # Added else if
            if (Team1Players = 0):
                PlayerReference1.Register(Agent)
                set Team1Players += 1
                Print("Registered in Team 1")
            else if (Team1Players = 1):
                PlayerReference2.Register(Agent)
                set Team1Players += 1
                Print("Registered in Team 1")
        else:
            Print("Team 1 is full")

```

Disclaimer: i haven’t tested it, but it does compile.

---

<div class="post-metadata">

**Author:** ![Frechfratze](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/frechfratze/32/932717_2.png) [@Frechfratze](https://forums.unrealengine.com/u/Frechfratze)\
**Post date:** [May 17, 2024, 6:26am UTC](https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910/3 "2024-05-17T06:26:57Z")

</div>

THANK YOU SO MUCH!

---

<div class="post-metadata">

**Author:** ![system](https://d3kjluh73b9h9o.cloudfront.net/original/4X/7/1/3/713c9d3f58553f0de89543d76a8a3a2779dc9fa4.png) [@system](https://forums.unrealengine.com/u/system)\
**Post date:** [June 16, 2024, 6:27am UTC](https://forums.unrealengine.com/t/verse-player-reference-device-capture-area/1858910/4 "2024-06-16T06:27:07Z")

</div>

This topic was automatically closed 30 days after the last reply. New replies are no longer allowed.
