# teleporting prop to player

**URL:** <https://forums.unrealengine.com/t/teleporting-prop-to-player/816093>\
**Category:** Verse\
**Created:** [March 24, 2023, 11:47am UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093 "2023-03-24T11:47:35Z")\
**Posts on this page:** 5\
**Page:** 1

<div class="post-metadata">

**Author:** ![Awesomebossdj7](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@Awesomebossdj7](https://forums.unrealengine.com/u/Awesomebossdj7)\
**Post date:** [March 24, 2023, 11:47am UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093/1 "2023-03-24T11:47:35Z")

</div>

I want to use a remote to teleport a prop to a player for a small amount of time,  
i’ve figured out how to teleport the prop, but i cant figure out how to get the player position

this is the code i have so far:

using { /Verse.org/Simulation }  
using { /Verse.org/Verse }  
using { /Fortnite.com/Devices }  
using { /Fortnite.com/Game }  
using { /Fortnite.com/Characters }

signalremote := class(creative\_device):

```
@editable
SignalRemoteManager:signal_remote_manager_device = signal_remote_manager_device{}
@editable
Prop:creative_prop = creative_prop{}

OnBegin<override>()<suspends> : void =
    SignalRemoteManager.PrimarySignalEvent.Subscribe(SignalRemotePrimarySignalEvent)

    
SignalRemotePrimarySignalEvent(Player:agent) : void = 
    Print("test")
    if (Prop.TeleportTo[]) {}

```

---

<div class="post-metadata">

**Author:** ![DiG3](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/dig3/32/1036114_2.png) [@DiG3](https://forums.unrealengine.com/u/DiG3)\
**Post date:** [March 24, 2023, 8:08pm UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093/2 "2023-03-24T20:08:31Z")

</div>

Hey, I’ve written a script that implements and explains how to do it.  
Feel free to ask about anything that’s not clear.

```auto
using { /Verse.org/Simulation }
using { /Verse.org/Verse }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Game }
using { /Fortnite.com/Characters }

# Teleports the given Prop to the Player after SecondsBeforeTeleport.
TeleportPropToPlayerAfterDelay<public>(Prop:creative_prop, InPlayer:player, SecondsBeforeTeleport:float)<suspends>:void=
    Sleep(SecondsBeforeTeleport)
    # Since we have multiple function calls that could fail, we can wrap all of them in a single
    # failure context (the if statement). If any of the function calls fail, the entire block will rollback.
    if:
        # We need to retrieve the fort_character from the player, which is the actual pawn that the player controls.
        FortCharacter := InPlayer.GetFortCharacter[]
        # fort_character implements the positional interface, which means we can call GetTransform on it.
        Transform := FortCharacter.GetTransform()
        Prop.TeleportTo[Transform.Translation, Transform.Rotation] 
    then:
        Print("Prop Teleported to Player!")

signal_remote_mover := class(creative_device):
    @editable
    SignalRemoteManager:signal_remote_manager_device = signal_remote_manager_device{}
    @editable
    Prop:creative_prop = creative_prop{}
    @editable
    SecondsBeforeTeleport:float = 1.0

    OnBegin<override>()<suspends>:void=
        SignalRemoteManager.PrimarySignalEvent.Subscribe(SignalRemotePrimarySignalEvent)
        
    SignalRemotePrimarySignalEvent<private>(Agent:agent):void= 
        # We need to make sure the Agent is actually a player by casting to the player type.
        if (TargetedPlayer := player[Agent]):
            # Since you'd like some delay before the prop teleports to the player, we'll use a coroutine.
            # A coroutine is created by `spawn`ing an asynchrounous (<suspends>) function.
            spawn{TeleportPropToPlayerAfterDelay(Prop, TargetedPlayer, SecondsBeforeTeleport)}

```

---

<div class="post-metadata">

**Author:** ![YouTube\_Samu](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@YouTube\_Samu](https://forums.unrealengine.com/u/YouTube_Samu)\
**Post date:** [March 29, 2023, 2:17pm UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093/3 "2023-03-29T14:17:50Z")

</div>

it doesn’t work for me, the prop doesn’t teleport to me

 ![image](https://d3kjluh73b9h9o.cloudfront.net/original/4X/a/d/d/add76e4d0159fe528d55b6fbb796b3c9a483318e.jpeg)

---

<div class="post-metadata">

**Author:** ![RycrooZ](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@RycrooZ](https://forums.unrealengine.com/u/RycrooZ)\
**Post date:** [April 10, 2023, 7:30am UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093/4 "2023-04-10T07:30:00Z")

</div>

Hi,  
do you have the script for the props to follow the player live  
thank you in advance

---

<div class="post-metadata">

**Author:** ![Wertandrew](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/wertandrew/32/916192_2.png) [@Wertandrew](https://forums.unrealengine.com/u/Wertandrew)\
**Post date:** [May 8, 2023, 2:09pm UTC](https://forums.unrealengine.com/t/teleporting-prop-to-player/816093/5 "2023-05-08T14:09:08Z")

</div>

I think its because of this line, players are now called agents

![chrome_dUVd0orNMr](https://d3kjluh73b9h9o.cloudfront.net/original/4X/d/c/8/dc8c5dc64a5baf4f060e471df8e548863f437312.jpeg)
