# Does someone know how to get SubscribeRoundEnded working  

**URL:** <https://forums.unrealengine.com/t/does-someone-know-how-to-get-subscriberoundended-working/2567914>\
**Category:** Verse\
**Tags:** unreal-editor-for-fortnite, fortnite-creative, question, fortnite\
**Created:** [June 20, 2025, 2:20pm UTC](https://forums.unrealengine.com/t/does-someone-know-how-to-get-subscriberoundended-working/2567914 "2025-06-20T14:20:51Z")\
**Posts on this page:** 3\
**Page:** 1

<div class="post-metadata">

**Author:** ![Rednes1234](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@Rednes1234](https://forums.unrealengine.com/u/Rednes1234)\
**Post date:** [June 20, 2025, 2:20pm UTC](https://forums.unrealengine.com/t/does-someone-know-how-to-get-subscriberoundended-working/2567914/1 "2025-06-20T14:20:52Z")

</div>

Does someone know how to get SubscribeRoundEnded working ( in Verse )?

---

<div class="post-metadata">

**Author:** ![BRGJuanCruzMK](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/brgjuancruzmk/32/1036548_2.png) [@BRGJuanCruzMK](https://forums.unrealengine.com/u/BRGJuanCruzMK)\
**Post date:** [August 8, 2025, 5:33pm UTC](https://forums.unrealengine.com/t/does-someone-know-how-to-get-subscriberoundended-working/2567914/2 "2025-08-08T17:33:56Z")

</div>

Hey @Rednes1234 how are you?

I’ve been trying for a couple hours to make it work but I couldn’t. You need to subscribe to that event for the Round Manager but I couldn’t find a way to get that Roound Manager in Verse, as you need an entity that contains it and get it from there.

This is what I’ve been testing so far:

**1) Approach with Round Settings device:**

```auto
using { /Fortnite.com/Devices }
using { /Fortnite.com/Game }
using { /Fortnite.com/Playspaces }
using { /Fortnite.com/Characters }
using { /Verse.org/Simulation }
using { /Verse.org/Assets }
using { /Verse.org/SceneGraph }
using { /UnrealEngine.com/Temporary/Diagnostics }

# See https://dev.epicgames.com/documentation/en-us/uefn/create-your-own-device-in-verse for how to create a verse device.

# A Verse-authored creative device that can be placed in a level
end_of_round_manager2 := class(creative_device):

    @editable
    RoundSettings : round_settings_device = round_settings_device{}

    var RoundEndedSubscription: ?cancelable = false

    OnBegin<override>()<suspends>: void =
        Print("Starting to listen the end of round")
        if(DeviceEntity := entity[RoundSettings]):
            if (RoundManager := DeviceEntity.GetFortRoundManager[]):
                Print("✅ Round Manager found from Round Settings Device")
                RoundManager.SubscribeRoundEnded(OnRoundEnded)
            else:
                Print("❌ No Round Manager found from Round Settings Device")
        else:
            Print("Device's entity not found")

    OnRoundEnded(): void =
        Print("💥 Round is Over!")
```

**2) Approach with players:**

```auto

using { /Fortnite.com/Devices }
using { /Fortnite.com/Game }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }
using { /Fortnite.com/Characters }
using { /Verse.org/Assets }
using { /Verse.org/SceneGraph }

# See https://dev.epicgames.com/documentation/en-us/uefn/create-your-own-device-in-verse for how to create a verse device.

# A Verse-authored creative device that can be placed in a level
end_of_round_manager := class(creative_device):

    # Runs when the device is started in a running game
    OnBegin<override>()<suspends>: void =
        Players := GetPlayspace().GetPlayers()
        if(Players.Length > 0):
            if(FirstPlayer := Players[0]):
                if(PlayerEntity := entity[FirstPlayer]):
                    if(RoundManager := PlayerEntity.GetFortRoundManager[]):
                        Print("✅ Round Manager found from the first player")
                        RoundManager.SubscribeRoundEnded(OnRoundEnded)
                    else:
                        Print("❌ No Round Manager found from first player")
    
    OnRoundEnded(): void =
        Print("💥 Round is Over!")
```

I don’t know if it possible to use that function right now in verse but if you tell me what are you trying to do I could probably help you with a different method to achieve the same result!

I’ll be waiting for your answer!

---

<div class="post-metadata">

**Author:** ![mobifruit](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/mobifruit/32/985104_2.png) [@mobifruit](https://forums.unrealengine.com/u/mobifruit)\
**Post date:** [November 13, 2025, 9:17pm UTC](https://forums.unrealengine.com/t/does-someone-know-how-to-get-subscriberoundended-working/2567914/3 "2025-11-13T21:17:22Z")

</div>

Yes, I do know now. Thanks for bringing it up!

As the Verse API documentation subtly hints:

> “This [fort\_round\_manager] interface is implemented by the round manager living on the **simulation entity**.“

So, I’ve adapted the above code to essentially:

```verse
if (SimEntity := GetSimulationEntity[]):
    if (RoundManager := SimEntity.GetFortRoundManager[]):
        Print("Subscribing to Round Manager events...")
        RoundManager.SubscribeRoundStarted(OnRoundStarted)
        RoundManager.SubscribeRoundEnded(OnRoundEnded)
    else:
        Print("Warning: Round Manager not found in Simulation entity")
else:
    Print("Error: Simulation not found")

```

Happy to say it functions in Fortnite on the first try 🤩

Ref. [Verse API reference page for the fort\_round\_manager interface | Fortnite Documentation | Epic Developer Community](https://dev.epicgames.com/documentation/en-us/fortnite/verse-api/fortnitedotcom/game/fort_round_manager)
