# DeactivateObjectivePulse has no effect on Map Indicator Pulse since 38.00

**URL:** <https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898>\
**Category:** Issues and Bug Reporting\
**Tags:** closed, fortnite-creative, unreal-editor-for-fortnite, fortnite\
**Created:** [November 2, 2025, 5:22am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898 "2025-11-02T05:22:33Z")\
**Posts on this page:** 14\
**Page:** 1

<div class="post-metadata">

**Author:** ![GraphicSurfer](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/graphicsurfer/32/1018702_2.png) [@GraphicSurfer](https://forums.unrealengine.com/u/GraphicSurfer)\
**Post date:** [November 2, 2025, 5:22am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/1 "2025-11-02T05:22:33Z")

</div>

### Summary

On one of my larger Verse scripts, I noticed that the Map Indicator Devices would not stop pulsing when deactivated per player agent.

To debug this, I created a minimal test script to determine whether this issue was specific to my implementation (e.g., a race condition) or a global bug.

Unfortunately, it appears to be global. I was able to reproduce the issue in a clean test environment.

Expected behavior:  
-When the switch is toggled ON, the pulse should start.  
-When the switch is toggled OFF, the pulse should stop.

Actual behavior:  
-After toggling the switch OFF, the pulse continues indefinitely and does not deactivate as expected.

Below is the Verse script I used to isolate and reproduce the issue:

```
using { /Verse.org/Simulation }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Playspaces }
using { /Verse.org/Concurrency }

pulse_tester := class(creative_device):

    @editable
    TestSwitch: switch_device = switch_device{}

    @editable
    TestIndicator: map_indicator_device = map_indicator_device{}

    # This function runs when the device starts
    OnBegin<override>()<suspends>:void=
        
        # Subscribe to the switch events
        TestSwitch.TurnedOnEvent.Subscribe(HandleTurnedOn)
        TestSwitch.TurnedOffEvent.Subscribe(HandleTurnedOff)

        # Make sure the map indicator is enabled when the game starts
        TestIndicator.Enable()
        
        # Check if the switch is set to "Per Player"
        if (TestSwitch.IsStatePerAgent[] = false):
            Print("WARNING: For this test, TestSwitch should have 'Store State Per Player' set to 'Yes'.")

        # Clean up any existing pulses for all players at the start
        AllPlayers := GetPlayspace().GetPlayers()
        for (Player : AllPlayers):
            TestIndicator.DeactivateObjectivePulse(Player)

    # This function runs when an agent turns the switch ON
    HandleTurnedOn(Agent: agent):void=
        Print("Pulse Tester: Switch Turned ON for player. Calling ActivateObjectivePulse...")
        TestIndicator.ActivateObjectivePulse(Agent)
        Print("Pulse Tester: ActivateObjectivePulse(Agent) has been called.")

    # This function runs when an agent turns the switch OFF
    HandleTurnedOff(Agent: agent):void=
        Print("Pulse Tester: Switch Turned OFF for player. Calling DeactivateObjectivePulse...")
        TestIndicator.DeactivateObjectivePulse(Agent)
        Print("Pulse Tester: DeactivateObjectivePulse(Agent) has been called.")

```

### Please select what you are reporting on:

Unreal Editor for Fortnite

### What Type of Bug are you experiencing?

Verse

### Steps to Reproduce

use DeactivateObjectivePulse(Agent) on Map Indicator Device in verse

### Expected Result

When the switch is toggled ON, the pulse should start.  
When the switch is toggled OFF, the pulse should stop.

### Observed Result

After toggling the switch OFF, the pulse continues indefinitely and does not deactivate as expected.

### Platform(s)

PC, Mobile (iphone 13)

---

<div class="post-metadata">

**Author:** ![Icifyed](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/icifyed/32/1038850_2.png) [@Icifyed](https://forums.unrealengine.com/u/Icifyed)\
**Post date:** [November 2, 2025, 5:30am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/2 "2025-11-02T05:30:02Z")

</div>

Ran into this problem as well. Disabling the device also doesn’t remove the pulse effect, it seems to be stuck permanently once assigned. This is a critical bug as it is extremely helpful in onboarding new players/tutorials.

---

<div class="post-metadata">

**Author:** ![L10NHEART](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/l10nheart/32/993801_2.png) [@L10NHEART](https://forums.unrealengine.com/u/L10NHEART)\
**Post date:** [November 2, 2025, 5:31am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/4 "2025-11-02T05:31:29Z")

</div>

Also encountering this issue; critical for us one one island as we use ObjectivePulse for a custom quest system (so there are 5+ pulses active at all times now).

---

<div class="post-metadata">

**Author:** ![Okita0707](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@Okita0707](https://forums.unrealengine.com/u/Okita0707)\
**Post date:** [November 2, 2025, 6:50am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/5 "2025-11-02T06:50:49Z")

</div>

Encounter the same issue, really hope this can be fixed, is very important to our game

---

<div class="post-metadata">

**Author:** ![FinestCreative](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/finestcreative/32/1034971_2.png) [@FinestCreative](https://forums.unrealengine.com/u/FinestCreative)\
**Post date:** [November 2, 2025, 10:19am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/6 "2025-11-02T10:19:11Z")

</div>

Also another bug, when you activate it the trail shows for all players [https://youtu.be/qQZnyg35ZHo](https://youtu.be/qQZnyg35ZHo)

---

<div class="post-metadata">

**Author:** ![xddRiu](https://d3kjluh73b9h9o.cloudfront.net/original/4X/2/8/5/28502927f1d97ba1051b3b47ccfe17233bf41ef0.png) [@xddRiu](https://forums.unrealengine.com/u/xddRiu)\
**Post date:** [November 2, 2025, 2:11pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/7 "2025-11-02T14:11:04Z")

</div>

Having the same issue, the pulse stays active even when a player completed a tracker in my map. Really hope this can be fixed as soon as possible

---

<div class="post-metadata">

**Author:** ![locutus](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/locutus/32/1093349_2.png) [@locutus](https://forums.unrealengine.com/u/locutus)\
**Post date:** [November 3, 2025, 1:21am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/9 "2025-11-03T01:21:20Z")

</div>

I can confirm this issue too in my maps where I am using Objective Pulse from a Map Indicator device. I am deactivating it by Direct Event Binding with a function “Deactivate Objective Pulse” by different actions, so it is not only related to Verse. It is happening in a map that was updated just a few hours ago and also in a map that was last updated a few weeks ago.

---

<div class="post-metadata">

**Author:** ![GraphicSurfer](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/graphicsurfer/32/1018702_2.png) [@GraphicSurfer](https://forums.unrealengine.com/u/GraphicSurfer)\
**Post date:** [November 3, 2025, 4:38pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/10 "2025-11-03T16:38:14Z")

</div>

https://www.youtube.com/embed/Oc7XaAXO94g?feature=oembed&wmode=opaque

Here’s a custom workaround that lets you take any creative prop and have it rotate toward a Map Indicator Device. This setup is designed to work alongside my custom Quest Manager, but you can easily adjust it to fit your own project.

```auto

    # Quest Arrow Manager 1.00.00
    # A replacement for the Map Indicator Pulse. Works in tandem with my Quest Manager, but with minor adjustments it can be adapted for your own needs.
    # If this code is helpful to you, please favorite me as a creator: https://www.fortnite.com/@graphicsurfer?lang=en-US
    # It costs nothing and means a lot. Thank you -GraphicSurfer.

    using { /Fortnite.com/Devices }
    using { /Fortnite.com/Characters }
    using { /Fortnite.com/Playspaces }
    using { /Verse.org/Simulation }
    using { /UnrealEngine.com/Temporary/SpatialMath }
    using { /Verse.org/Verse } 

    quest_arrow_manager_device := class(creative_device):

        # --- Arrow Prop Arrays ---
        @editable
        MainQuestArrows: []creative_prop = array{}
        @editable
        SideQuestArrows: []creative_prop = array{}
        @editable
        OptionalQuestArrows: []creative_prop = array{}

        # --- Shared Settings ---
        @editable
        ArrowOffset: vector3 = vector3{X := 0.0, Y := 0.0, Z := 150.0}
        @editable
        UpdateRate: float = 0.064
        @editable
        Smoothness: float = 20.0

        # --- State Variables ---
        var MainPropScales: []vector3 = array{}
        var SidePropScales: []vector3 = array{}
        var OptionalPropScales: []vector3 = array{}

        var MainQuestTargetMap: [player]?map_indicator_device = map{}
        var SideQuestTargetMap: [player]?map_indicator_device = map{}
        var OptionalQuestTargetMap: [player]?map_indicator_device = map{}

        var PlayerArrowIndexMap: [player]?int = map{}
        var AvailableArrowIndices: []int = array{}

        HiddenLocation: vector3 = vector3{X := 0.0, Y := 0.0, Z := -1000.0}

        OnBegin<override>()<suspends>:void=
            for (Arrow : MainQuestArrows):
                set MainPropScales = MainPropScales + array{Arrow.GetTransform().Scale}
            for (Arrow : SideQuestArrows):
                set SidePropScales = SidePropScales + array{Arrow.GetTransform().Scale}
            for (Arrow : OptionalQuestArrows):
                set OptionalPropScales = OptionalPropScales + array{Arrow.GetTransform().Scale}

            for (Index -> Arrow : MainQuestArrows):
                set AvailableArrowIndices += array{Index}

            Playspace := GetPlayspace()

            for (Player : Playspace.GetPlayers()):
                spawn{ OnPlayerAdded(Player) }
            
            Playspace.PlayerAddedEvent().Subscribe(OnPlayerAddedWrapper)
            Playspace.PlayerRemovedEvent().Subscribe(OnPlayerRemoved)

            loop:
                InterpFactor := Clamp(Smoothness * UpdateRate, 0.0, 1.0)
                AllPlayers := Playspace.GetPlayers()

                for (Player : AllPlayers):
                    if (StablePlayerIndex := PlayerArrowIndexMap[Player]?):
                        if (PlayerCharacter := Player.GetFortCharacter[]):
                            PlayerLocation := PlayerCharacter.GetTransform().Translation

                            # --- Main Quest ---
                            if (MainArrow := MainQuestArrows[StablePlayerIndex]):
                                if (MainScale := MainPropScales[StablePlayerIndex]):
                                    if (CurrentTarget := MainQuestTargetMap[Player]?):
                                        UpdateArrowMovement(MainArrow, CurrentTarget, PlayerLocation, MainScale, InterpFactor)
                                    else:
                                        HideArrow(MainArrow, MainScale)
                            
                            # --- Side Quest ---
                            if (SideArrow := SideQuestArrows[StablePlayerIndex]):
                                if (SideScale := SidePropScales[StablePlayerIndex]):
                                    if (CurrentTarget := SideQuestTargetMap[Player]?):
                                        UpdateArrowMovement(SideArrow, CurrentTarget, PlayerLocation, SideScale, InterpFactor)
                                    else:
                                        HideArrow(SideArrow, SideScale)
                            
                            # --- Optional Quest ---
                            if (OptionalArrow := OptionalQuestArrows[StablePlayerIndex]):
                                if (OptionalScale := OptionalPropScales[StablePlayerIndex]):
                                    if (CurrentTarget := OptionalQuestTargetMap[Player]?):
                                        UpdateArrowMovement(OptionalArrow, CurrentTarget, PlayerLocation, OptionalScale, InterpFactor)
                                    else:
                                        HideArrow(OptionalArrow, OptionalScale)
                
                Sleep(UpdateRate)

        OnPlayerAddedWrapper(Player: player):void=
            spawn{ OnPlayerAdded(Player) }

        OnPlayerAdded(Player: player)<suspends>:void=
            if (PlayerArrowIndexMap[Player]?):
                return

            if (AvailableArrowIndices.Length = 0):
                Print("QuestArrowManager: CRITICAL - No available arrow indices for new player!")
                return

            var CurrentIndex: int = 0
            if (IndexValue := AvailableArrowIndices[0]):
                set CurrentIndex = IndexValue
                var NewAvailableIndices: []int = array{}
                for (I := 1..AvailableArrowIndices.Length - 1):
                    if (Index := AvailableArrowIndices[I]):
                        set NewAvailableIndices += array{Index}
                set AvailableArrowIndices = NewAvailableIndices
            else:
                Print("QuestArrowManager: Failed to get CurrentIndex from AvailableArrowIndices")
                return

            if (set PlayerArrowIndexMap[Player] = option{CurrentIndex}):

                if (set MainQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear MainQuestTargetMap in OnPlayerAdded")

                if (set SideQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear SideQuestTargetMap in OnPlayerAdded")
                    
                if (set OptionalQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear OptionalQuestTargetMap in OnPlayerAdded")

                Print("QuestArrowManager: Assigned arrow index {CurrentIndex} to new player.")
            else:
                Print("QuestArrowManager: CRITICAL - Failed to set PlayerArrowIndexMap.")

        OnPlayerRemoved(Player: player):void=
            if (Index := PlayerArrowIndexMap[Player]?):
                Print("QuestArrowManager: Player left. Cleaning up index {Index}.")
                

                if (set MainQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear MainQuestTargetMap in OnPlayerRemoved")
                    
                if (set SideQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear SideQuestTargetMap in OnPlayerRemoved")
                    
                if (set OptionalQuestTargetMap[Player] = false):

                else:
                    Print("QuestArrowManager: Failed to clear OptionalQuestTargetMap in OnPlayerRemoved")

                
                if (set PlayerArrowIndexMap[Player] = false):
                    Print("QuestArrowManager: Player removed from index map.")
                    set AvailableArrowIndices += array{Index}
                else:
                    Print("QuestArrowManager: FAILED to remove player from index map.")

        UpdateArrowMovement(ArrowProp: creative_prop, TargetDevice: map_indicator_device, PlayerLocation: vector3, PropScale: vector3, InterpFactor: float)<suspends>:void=
            TargetLocation := TargetDevice.GetTransform().Translation
            TargetArrowLocation := PlayerLocation + ArrowOffset

            Direction := vector3{
                X := TargetLocation.X - PlayerLocation.X,
                Y := TargetLocation.Y - PlayerLocation.Y,
                Z := 0.0
            }

            if (NormalizedDirection := Direction.MakeUnitVector[]):
                XForward := vector3{X := 1.0, Y := 0.0, Z := 0.0}
                TargetArrowRotation := MakeShortestRotationBetween(XForward, NormalizedDirection)

                CurrentTransform := ArrowProp.GetTransform()
                CurrentLocation := CurrentTransform.Translation
                CurrentRotation := CurrentTransform.Rotation
                
                NewLocation := Lerp(CurrentLocation, TargetArrowLocation, InterpFactor)
                
                if (NewRotation := Slerp[CurrentRotation, TargetArrowRotation, InterpFactor]):
                    NewTransform := transform{
                        Translation := NewLocation,
                        Rotation := NewRotation,
                        Scale := PropScale
                    }

                    if (ArrowProp.TeleportTo[NewTransform]):

                    else:
                        Print("QuestArrowManager: TeleportTo failed.")

        HideArrow(ArrowToHide: creative_prop, PropScale: vector3)<transacts>:void=
            HiddenTransform := transform{
                Translation := HiddenLocation,
                Rotation := IdentityRotation(),
                Scale := PropScale
            }
            
            if (ArrowToHide.TeleportTo[HiddenTransform]):

            else:
                Print("QuestArrowManager: HideArrow TeleportTo failed.")

        ActivateMainQuestArrow<public>(Player: player, Target: map_indicator_device)<transacts>:void=
            if (set MainQuestTargetMap[Player] = option{Target}):

            else:
                Print("QuestArrowManager: Failed to set MainQuestTargetMap.")

        DeactivateMainQuestArrow<public>(Player: player)<transacts>:void=
            if (set MainQuestTargetMap[Player] = false):

            else:
                Print("QuestArrowManager: Failed to clear MainQuestTargetMap.")

        ActivateSideQuestArrow<public>(Player: player, Target: map_indicator_device)<transacts>:void=
            if (set SideQuestTargetMap[Player] = option{Target}):

            else:
                Print("QuestArrowManager: Failed to set SideQuestTargetMap.")

        DeactivateSideQuestArrow<public>(Player: player)<transacts>:void=
            if (set SideQuestTargetMap[Player] = false):

            else:
                Print("QuestArrowManager: Failed to clear SideQuestTargetMap.")

        ActivateOptionalQuestArrow<public>(Player: player, Target: map_indicator_device)<transacts>:void=
            if (set OptionalQuestTargetMap[Player] = option{Target}):

            else:
                Print("QuestArrowManager: Failed to set OptionalQuestTargetMap.")

        DeactivateOptionalQuestArrow<public>(Player: player)<transacts>:void=
            if (set OptionalQuestTargetMap[Player] = false):

            else:
                Print("QuestArrowManager: Failed to clear OptionalQuestTargetMap.")

```

---

<div class="post-metadata">

**Author:** ![AtAshTag](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/atashtag/32/997253_2.png) [@AtAshTag](https://forums.unrealengine.com/u/AtAshTag)\
**Post date:** [November 3, 2025, 4:42pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/11 "2025-11-03T16:42:10Z")

</div>

Use this…

I have always used this ever since issues started happening 1yr+ ago

 ![image](https://d3kjluh73b9h9o.cloudfront.net/original/4X/1/1/d/11df542443f0f4f5223668ddc7227cb03bb5ec1d.png)

[https://dev.epicgames.com/community/snippets/90ma/fortnite-compass-device](https://dev.epicgames.com/community/snippets/90ma/fortnite-compass-device)

Credit to the creator.

Its easy to setup and has the images ect super useful 🙂

All you do is pass the location in/player ect and bam works like a charm

---

<div class="post-metadata">

**Author:** ![Flak](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/flak/32/769441_2.png) [@Flak](https://forums.unrealengine.com/u/Flak)\
**Post date:** [November 3, 2025, 5:41pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/12 "2025-11-03T17:41:31Z")

</div>

For tracking: [Fortnite Ecosystem 38.00 Known Issues Thread - #12 by Flak](https://forums.unrealengine.com/t/fortnite-ecosystem-38-00-known-issues-thread/2670848/12)

---

<div class="post-metadata">

**Author:** ![MACKJACK](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/mackjack/32/919178_2.png) [@MACKJACK](https://forums.unrealengine.com/u/MACKJACK)\
**Post date:** [November 6, 2025, 10:09pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/14 "2025-11-06T22:09:16Z")

</div>

Confirming we also have this issue on a couple maps

---

<div class="post-metadata">

**Author:** ![chrisp\_games](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/chrisp_games/32/895155_2.png) [@chrisp\_games](https://forums.unrealengine.com/u/chrisp_games)\
**Post date:** [November 10, 2025, 9:52am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/15 "2025-11-10T09:52:09Z")

</div>

Can confirm this happening as well

---

<div class="post-metadata">

**Author:** ![Bug-Reporter](https://d1ap1mz92jnks1.cloudfront.net/user_avatar/forums.unrealengine.com/bug-reporter/32/997076_2.png) [@Bug-Reporter](https://forums.unrealengine.com/u/Bug-Reporter)\
**Post date:** [November 10, 2025, 9:36pm UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/16 "2025-11-10T21:36:01Z")

</div>

FORT-1006729 has been ‘Closed’ as a duplicate of an existing known issue. Origin Issue: FORT-989502, Origin Topic: [Map indicator pulse doesn't deactivate](https://forums.unrealengine.com/t/map-indicator-pulse-doesnt-deactivate/2671126)

---

<div class="post-metadata">

**Author:** ![system](https://d3kjluh73b9h9o.cloudfront.net/original/4X/7/1/3/713c9d3f58553f0de89543d76a8a3a2779dc9fa4.png) [@system](https://forums.unrealengine.com/u/system)\
**Post date:** [May 1, 2026, 5:22am UTC](https://forums.unrealengine.com/t/deactivateobjectivepulse-has-no-effect-on-map-indicator-pulse-since-38-00/2670898/17 "2026-05-01T05:22:58Z")

</div>

This topic was automatically closed after 180 days. New replies are no longer allowed.
